PROGRAM AERMOD
!***********************************************************************
!           MAIN Module of the AMS/EPA Regulatory Model - AERMOD
!                       (DRAFT Version Dated 04300)
!
!               *** SEE AERMOD MODEL CHANGE BULLETIN MCB#X ***
!
!       ON THE SUPPORT CENTER FOR REGULATORY AIR MODELS (SCRAM) WEBSITE
!
!                      http://www.epa.gov/scram001/
!
!=======================================================================
!
!       This DRAFT version (dated 04300) includes the Plume Volume Molar
!       Ratio Method (PVMRM) and the Ozone Limiting Method (OLM) for
!       modeling conversion of NOx to NO2.  This work was supported by
!       BP Exploration (Alaska), Inc., Phillips Exploration, Inc.,
!       and the Alaska Department of Environmental Conservation.
!
!       This DRAFT version (dated 04300) also includes the following
!       modifications:
!
!       1.  Dry depletion (DRYDPLT) and wet depletion (WETDPLT) are no
!           longer optional for deposition applications.  These options
!           for removal of mass from the plume due to dry and/or wet
!           deposition processes will automatically be invoked for
!           applications in which dry and/or wet deposition are
!           considered.  The DRYDPLT and WETDPLT options on the
!           MODELOPT card will be ignored, and need not be removed
!           from the model input file for the model to run.
!
!       2.  Correction made to area source algorithm, subroutine PLUMEF,
!           to include a call to CRITDS to calculate the critical
!           dividing streamline height for gaseous pollutants.  Also
!           modified PLUMEF to correct a problem with the AREADPLT option.
!
!       3.  Corrections made to area source and openpit algorithms,
!           in subroutines ACALC and OCALC, to include tilted plume
!           for point source approximation of particle emissions, and
!           to include reinitialization of __VAL arrays at end of
!           receptor loop (reinitializations also included in PCALC and
!           VCALC for point and volume sources for consistency).  The
!           latter correction fixes a potential problem with particle
!           emissions for area sources when the point source
!           approximation is used under the TOXICS option.
!
!       4.  Corrected calling arguments for call to WAKE_SIG from
!           subroutine WAKE_DFSN2, to use wakiz and wakiy instead of
!           turbz and turby.
!
!       5.  Minor correction made to wet deposition calculations to
!           include lateral term (FSUBY) in weighting of direct
!           and penetrated source contributions for WETFLUX.
!
!       6.  Modified suroutine PRMCALC to place receptor on centerline
!           of cavity plumes by setting Y2 = 0.0 for SCREEN option.
!
!       7.  Modified subroutine SRCQA to calculate equivalent XINIT
!           and YINIT values for AREAPOLY sources to allow for
!           calculation of area of source under TOXICS option and
!           for PVMRM option.  Also modified SRCQA to include a more
!           refined computation of centroid for AREAPOLY sources.
!
!       8.  Included check in subroutine METQA for absolute values of
!           Monin-Obukhov length (OBULEN) less than 1.0.  Adjustment
!           of OBULEN is made to limit ABS(OBULEN) .GE. 1.0.  The
!           sign of OBULEN is assigned the opposite of the sign of the
!           heat flux if OBULEN is 0.0.  This limit on OBULEN is
!           already applied in AERMET, so this change in AERMOD will
!           only affect input data generated by other means.
!
!       9.  Moved call to SUB. METDAT ahead of call to SUB. SET_METDATA
!           to avoid potential problem with negative (missing)
!           precipitation for first hour.
!
!      10.  Added range check on gas deposition parameters to trap
!           on input of zero (0.0) values.
!
!      11.  Modified subroutine METQA to reduce number of extraneous
!           warning messages, especially for hours with missing
!           meteorological data.  Also modified range check for missing
!           wind direction in subroutine CHKMSG.
!
!      12.  Modified PLOTFILE output to include date field.
!
!      13.  Modifications to some debug output statements based on
!           code provided by ENSR.
!
!       MODIFIED BY:    Roger W. Brode
!                       MACTEC Federal Programs, Inc.
!                       (formerly known as PES, Inc.)
!                       October 26, 2004
!
!       MODIFIED FROM:          AERMOD
!                       (Version Dated 04079)
!
!=======================================================================
!
!       This revised DRAFT version (dated 04079) incorporates
!       modifications to the wet deposition algorithms for both
!       gaseous and particle emissions.  For both gaseous and particle
!       wet deposition, the wet fluxes have been corrected to include
!       a factor of 3600.*SQRT(2*PI) in the denominator.  The factor
!       of 3600 was needed to correct a unit conversion error between
!       seconds and hours in the final calculation of the flux.
!       The factor of SQRT(2*PI) is needed to complete the integrated
!       vertical term.  A problem causing potential runtime errors for
!       volume and area sources with dry depletion was also corrected.
!
!       In addition to the corrections identified above, the particle
!       wet deposition algorithms were also modified to include an
!       algorithm for calculating the collision efficiency as a function
!       of particle size and raindrop size.  The previous version of
!       the model included a fixed value of 4.0e-4 for the collision
!       efficiency.
!
!
!       MODIFIED BY:    Roger W. Brode
!                       MACTEC Federal Programs, Inc.
!                       (formerly known as PES, Inc.)
!                       March 19, 2004
!
!       MODIFIED FROM:           AERMOD
!                         (Version Dated 03273)
!
!=======================================================================
!
!       This DRAFT version (dated 03273) incorporates wet and dry
!       deposition algorithms based on the draft ANL report (Wesely,
!       et. al, 2001), with modifications to the wet deposition
!       algorithms based on peer review comments.  The dry deposition
!       algorithms include dry depletion based on the simple source
!       depletion method.
!
!       NOTE:  The wet SCIM'ing and output by particle size options
!       from the ISCST3 model have not been implemented yet in AERMOD.
!
!       This version includes the following modifications relative to
!       the previous draft (dated 03213):
!
!       1.  Removed depletion for the "inside cavity source" from the
!           PRIME calculations.
!
!       2.  Moved the code to adjust for TS < TA (used to model a fixed
!           delta TS-TA) from SUBROUTINE SETSRC back to SUBROUTINE
!           FLUXES.  This corrects some minor discrepancies between
!           the consequence analysis results for non-buoyant sources
!           relative to version 02222.
!
!       3.  Removed the dry particle deposition code associated with
!           DFAULT mode in ISCST3.  The only dry particle deposition
!           in AERMOD is based on the ANL report for Methods 1 and 2.
!           This also corrects a logic problem if neither TOXICS nor
!           DFAULT options are specified.
!
!       4.  Modified FUNCTION F2INT to only call DELTAH for point
!           sources during plume depletion calculation.
!
!       5.  Added identification of urban sources and Method 2 sources
!           in summary of source inputs.
!
!       6.  Included optional dry depletion option for Method 2.
!
!       7.  Additional code cleanup and documentatino, including removal
!           of unused data arrays associated with ISCST3 depletion code
!           and moving the call to SUBROUTINE METINI to follow the call
!           to SETSRC in SUBROUTINE OCALC for open pit sources.
!
!
!       Version 03213 (August 1, 2003) included the following
!       modifications relative to the previous draft (dated 03171):
!
!       1.  Corrects problem with calculation of f2 term used in gas
!           dry deposition.  The calculation of Wnew and f2 had to be
!           moved outside the source loop to properly account for
!           accumulated precipitation over three hour period.
!
!       2.  Changed the definition of the "top of the plume" to be based
!           on the plume centerline height plus 2.15*sigma-z, evaluated
!           at 20km downwind.  The previous definition was based on
!           3.9*sigma-z.
!
!       3.  Terrain effects are now incorporated in the dry depletion
!           calculation.  The terrain elevation is linearly interpolated
!           between the source base elevation and the terrain elevation
!           at the receptor.  The hill height scale is linearly
!           interpolated between the stack release height at the
!           source and the hill height scale from AERMAP at the receptor
!           location.
!
!       4.  Modified the short-term EVENT processing option to be
!           compatible with the deposition algorithms.  If more than
!           one output type is selected in the normal model run that
!           generates the EVENT input file, the events will be defined
!           based on the first output type, in the order of CONC, DEPOS,
!           DDEP, WDEP.
!
!       5.  Modified summary of first 24-hours of met data to include
!           additional parameters for deposition applications.
!
!       6.  Modified the program to use free-formatted READ for the
!           surface meteorological input file for all cases.  Decision
!           on whether to read additional parameters needed for deposition
!           is based on logical variables associated with deposition
!           calculations.
!
!       7.  Incorporated a patch in SUBROUTINE UNLUMP of PRIME.FOR to
!           avoid potential math error for downwash calculations.
!           The plume temperature calculated by NUMRISE is limited to
!           be greater than or equal to the ambient temperature minus
!           10 K.  This avoids a potential SQRT of a negative number.
!
!       MODIFIED BY:    Roger W. Brode
!                       MACTEC Federal Programs, Inc.
!                       (formerly known as PES, Inc.)
!                       September 30, 2003
!
!       MODIFIED FROM:           AERMOD
!                         (Version Dated 02222)
!
!=======================================================================
!
!       This DRAFT version (dated 02222) includes fixes to the following
!       bugs:
!
!       1) modification to ACALC to avoid potential math errors
!          for AREAPOLY sources;
!       2) correction to METSUM to output missing temperatures correctly
!          for the SCIM option;
!       3) correction to EMVARY to replace 'STAR' option with
!          'WSPEED' option;
!       4) modified CAV_SRC to keep "outside" cavity source in array
!          element 3 for cases when no "inside" cavity source contribution
!          occurs;
!       5) corrected meander algorithm to combine "plume" and
!          "pancake" components of concentrations rather than just
!          blending the lateral dispersion term, removed limit on pancake
!          term to be smaller than plume lateral term, and removed meander
!          from the PRIME component for sources subject to building
!          downwash;
!       6) corrected problem in NUMRISE to avoid referencing an
!          undefined variable (xbi);
!       7) corrected calling arguments for call to WAKE_SIG from
!          subroutine WAKE_DFSN, to use wakiz and wakiy instead of
!          turbz, and turby; and
!       8) correction of Z_iuo in subroutine URBCALC from 500 to 400
!          meters.
!
!       Modified to remove command line arguments for specifying
!       input and output file names, and use hardwired names of
!       AERMOD.INP and AERMOD.OUT.
!
!       This version includes an adjustment to ustar and L for urban stable
!       cases, by equating the "convective" sigma-w based on the urban
!       "convective" w* with the mechanical sigma-w based on u*
!       evaluated at a height of 7 times the urban roughness length.
!       The URBANOPT keyword was modified to allow the user to input
!       the urban roughness length as an optional parameter following
!       the optional city name.  If no urban roughness length is input,
!       then the model assumes an urban roughness length of 1.0 meter.
!
!       This version also includes a modification to the minimum layer
!       depth near the ground used to calculate effective parameters.
!       A minimum layer depth of 5 meters is used instead of 2 meters
!       if the plume centroid height and receptor height are both below
!       5 meters.
!
!       MODIFIED BY:    Roger W. Brode
!                       PES, Inc.
!                       September 10, 2002
!
!       MODIFIED FROM:           AERMOD
!                         (Version Dated 01247)
!
!=======================================================================
!
!       This draft version (dated 01247) includes the PRIME building
!       downwash algorithms based on the ISC-PRIME model (dated 99207).
!       For cases involving building downwash, the model calculates a
!       non-wake contribution using the AERMOD algorithms, a wake
!       contribution using the PRIME algorithms, and blends the two
!       results using a factor called GAMFACT that varies based on the
!       location of the receptor relative to the wake.  For receptors
!       within the wake region, where the lateral and vertical boundaries
!       are defined by the wake half-width and height, respectively, and
!       the longitudinal boundary is defined by a distance equal to 15R
!       or the point where wake turbulence intensity decays to ambient
!       turbulence intensity, whichever is greater, measured from the
!       upwind edge of the building, GAMFACT is set equal to 1.0 (i.e.,
!       uses the PRIME result only).  The PRIME algorithm has been
!       modified to use the AERMOD meteorological profiles and
!       definitions of ambient turbulence.
!
!       This version also includes a modification to the DTHETA/DZ
!       profile (TEMPGRID.FOR) for extrapolating above the highest
!       measurement height for cases with observed temperature profiles,
!       a modification to the upper limit on the integration for
!       HCRIT (CALC2.FOR), a correction to the calculation of FYPAN
!       for meander (CALC2.FOR), and an adjustment to ISTRT_WIND used
!       for Y2K compliance to subtract 1 from ISTRT_WIND in case the
!       meteorological data file contains data from the end of the
!       previous year.
!
!       MODIFIED BY:    Roger W. Brode
!                       PES, Inc.
!                       September 4, 2001
!
!       MODIFIED FROM:           AERMOD
!                         (Version Dated 00357)
!
!=======================================================================
!
!       This version (dated 00357) includes enhancements based on the
!       current ISCST3 model (dated 00101).  These include:  1) the use of
!       globally allocatable arrays for data storage; 2) expanded data
!       structures to allow for output of concentration and deposition in
!       a single model run (for use when deposition algorithms are added
!       to AERMOD); 3) EVENT processing for short-term culpability analyses;
!       4) post-1997 PM10 processing; 5) TOXICS option enhancements such as
!       optimizations for area sources, the SCIM option, and SEASONHR output
!       file option; 6) explicit treatment of multiple-year meteorological
!       data files and ANNUAL averages; 7) the SHRDOW and SHRDOW7 options
!       for specifying emissions that vary by season, hour-of-day, and
!       day-of-week; and 8) improved data structures for field length and
!       filename lengths.
!
!       The following modifications have also been made to correct errors:
!       1) the PARAMETER LAMDAY was implicitly typed as integer in previous
!       versions, and is now explicitly typed as real, which has an impact
!       on the plume height calculations for the indirect source; 2) the
!       calculation of the plume centroid height for unstable conditions
!       for area sources was moved from SUB. ACALC to be included inside
!       the area source integration in SUB. PLUMEF and SUB. PWIDTH, which
!       affects results for area sources during unstable conditions,
!       especially for receptors located inside an elongated area source
!       with the wind blowing along the long dimension of the source; and
!       3) the STABLE and UNSTAB logical variables are now assigned prior
!       to the call to COMPTG in SUB. METEXT, potentially affecting the
!       observed DTHETA/DZ profile for the first stable hour in a day;
!       4) the calculation of wind direction (WDIR) at stack top in SUB.
!       METINI and at stack height plus 0.5*deltaH in SUB. PCALC was
!       corrected to account for possible 0-360 crossover in the profile;
!       5) corrections were made to the vertical terms to correct the
!       reflection component for receptors located below stack base elevation;
!       6) corrected calculation of FYPAN term for meander in SUB. FYTERM
!       to use radial distance (DISTR) instead of downwind distance (X); and
!       7) application of meander to both stable and unstable conditions.
!       Additional modifications were made to consolidate redundant code
!       and simplify future maintenance activities.
!
!       MODIFIED BY:    Roger W. Brode
!                       PES, Inc.
!                       December 22, 2000
!
!       MODIFIED FROM:           AERMOD
!                         (Version Dated 99351)
!
!========================================================================
!
!                              (Version Dated 99351)
!                                December 17, 1999
!
!        This version (99351) includes the following corrections to the
!        implementation of the Schulman-Scire downwash algorithm:  1) added
!        call to DHPSS in calculation of plume centroid height (CENTER) in
!        subroutine PCALC; and 2) modified to use SZ3LB and SY3LB based on
!        building enhanced dispersion curves only in subroutine DHPSS.
!        Additional modifications were made to improve consistency with
!        ISCST3 implementation of Schulman-Scire downwash algorithm.
!        Also includes changes to subroutine PCCODE to facilitate
!        compilation of the model using the DEC Visual Fortran compiler.
!        The output file unit number, IOUNIT, was also changed from 6 to 9
!        in order for runtime status update to appear on the screen for
!        DEC-compiled executables.  Minor, inconsequential changes were
!        also made to comment headers and variable declarations in
!        SIGGRID.FOR.
!
!
!        MODIFIED FROM:
!                              (Version Dated 99211)
!                                  July 30, 1999
!
!========================================================================
!
!        This version (99211) incorporates modifications for Y2K compliance.
!        Uses a window of 1950 to 2049 for 2-digit years.  Will utilize
!        4-digit year if input for surface and profile files using FREE
!        format (the default read format still reads a 2-digit year).
!        Changes also include calculation of a 10-digit date variable
!        (FULLDATE) with 4-digit year for date comparisons, and changes of
!        the output formats for the 8-digit variable, KURDAT, to I8.8 to
!        include leading zeros.  The date and time routines used for the
!        page headers have been modified to use the standard Fortran 90
!        routines, and minor changes have been made to remove obsolescent
!        features from the code.  Changes also include a correction to
!        a variable name in SUBROUTINE DELTAH.
!
!
!        MODIFIED FROM:
!                              (Version Dated 98314)
!                                November 10, 1998
!
!========================================================================
!
!        This version (dated 98314) incorporates modifications for the final
!        draft AERMOD Model. This draft represents the final version of the
!        model prior to the Notice of Proposed Rulemaking for including
!        AERMOD in the modeling Guideline and subsequent public comment period.
!        Changes to the model are too numerous to list here in detail.
!        Changes to the interface are incorporated in the revised
!        AERMOD user's guide, and pertain primarily to the regulatory
!        default option on the CO MODELOPT card, and removal of the
!        developmental options for terrain affects.  The CO TERRHGTS
!        keyword is now obsolete, and a new mandatory ME PROFBASE
!        keyword has been added for inputting the base elevation above
!        MSL for the gridded potential temperature profile.
!
!
!        MODIFIED FROM:
!                               (Version Dated 98022)
!                                  January 22, 1998
!
!========================================================================
!
!        This version (dated 98022) incorporates modifications for the revised
!        draft AERMOD Model. This draft represents the final Phase I version
!        of the model.  This version includes the use a minimum sigma-v of
!        0.2 m/s. It also incorporates corrections to the downwash algorithms.
!        It limits the number of iterations on inhomogeneity to 1,
!        i.e., effective parameters are calculated based on an average
!        for the layer from plume centerline to 2.15 sigma-z, where
!        sigma-z is based on parameters at plume centerline height.
!        The transport wind direction is based on the modpoint between
!        stack height and "final" plume height.  Modifications have also
!        been made to the dtheta/dz profile, the Tly and Tlz used for stable
!        plumes above the CBL, and the height of the effective reflecting
!        surface for stable plumes.
!
!
!        MODIFIED FROM:
!                               (Version Dated 97350)
!                                 December 16, 1997
!
!========================================================================
!
!        This draft includes an option for specifying the transport wind
!        direction.  The option is specified on the MODELOPT card, where
!        WDOPT1 is for wind direction taken at stack height, and
!        WDOPT2 is for wind direction at the midpoint between stack height
!        and "final" plume height.  The default option is WDOPT1.
!        This version does not include conditional compilation code to
!        support the Microsoft Fortran compiler.  This version of the
!        code is compatible with the Lahey F77L3 and Lahey LF/90 compilers.
!        The deposition algorithm for AERMOD is still under development,
!        and is not operational in this version.
!                   R.W. Brode, PES, Inc., December 16, 1997
!
!
!        MODIFIED FROM:
!                               (Version Dated 97064)
!                                   March 5, 1997
!
!========================================================================
!
!        Incorporates modifications for second round of Beta Testing,
!        including code clean-up and removing obsolete options.  Since
!        the urban stable boundary layer algorithm in AERMOD is still
!        under development, the keywords for implementing the urban
!        option in AERMOD have been disabled for this revised draft
!        Beta release of the model.
!                   R.W. Brode, PES, Inc., March 5, 1997
!
!        MODIFIED FROM:
!                               (Version Dated 96239)
!                                   August 26, 1996
!
!========================================================================
!
!        Includes modification to wind direction gridded profiling in
!        SUB. GRDWD, correcting a problem with wind directions backing
!        through 360 degrees.  This could result in a level of observed
!        wind direction being erroneously counted as missing.
!                   R.W. Brode, PES, Inc., August 26, 1996
!
!        MODIFIED FROM:
!                               (Version Dated 96228)
!                                   August 15, 1996
!
!========================================================================
!
!        Includes modifications for low wind/low turbulence cases.  Also
!        changed definition of "valid lower bound" to be 7zo instead of
!        20zo for consistency with recent changes to AERMET.  The terrain
!        options have also been reinstated on the CO MODELOPT card as
!        TERROPT1 and TERROPT2.  The command line developmental option
!        switch has been enabled in this version.
!                   R.W. Brode, PES, Inc., August 15, 1996
!
!        MODIFIED FROM:
!
!                               (Version Dated 96198)
!                                    July 16, 1996
!
!========================================================================
!
!        Includes Urban Boundary Layer Option based on the Model Coding
!        Abstract by Akula Ventkatram dated 4/1/96.  Modified inputs
!        include two new keywords:
!
!                 CO URBANOPT  Urbpop  (Urbnam)
!                    where Urbpop is the population of the urban area, and
!                          Urbnam is an optional character field
!                          for the name of the urban area.
!
!                 SO URBANSRC  Srcid's  and/or  Srcrng's
!                    where Srcid's identifies individual sources to be
!                          modeled as urban sources, and Srcrng's
!                          identifies a range of sources to be modeled
!                          as urban.
!
!
!        MODIFIED FROM:
!                               (Version Dated 96131)
!                                    May 10, 1996
!
!        Includes OPTG3 and OPTG4 for stable plume reflection options.
!
!        MODIFIED FROM:
!                               (Version Dated 96053)
!                                 February 22, 1996
!
!        Includes flow vector, AFV, in the EVALFILE output.
!
!        MODIFIED FROM:
!                               (Version Dated 96046)
!                                 February 15, 1996
!
!        Includes new sigma-v and sigma-w profiles coded by Bob Paine,
!        some modifications to TEMPGRID.FOR to avoid discontinuities in
!        the VPTG profile, reinstates command-line input for developmental
!        options for the Lahey version, modifies the default option settings
!        to remove stable plume reflections, reinstates the original stable
!        profile for TLz, increases the maximum number of iterations in
!        IBLVAL from 5 to 20, and includes patches for smoothed h < 0 and
!        for mixing heights at (or near) 5,000m.
!                   R.W. Brode, PES, Inc., February 15, 1996
!
!        MODIFIED FROM:
!                               (Version Dated 95272)
!
!        Includes a SCREEN mode option on CO MODELOPT card,
!        addition of AREAPOLY and AREACIRC source types,
!        and INCLUDED keyword option for including data from
!        an external file for the SO and RE pathways.  The
!        INCLUDED option is intended as a link to AERMAP and
!        for use with the screening version of AERMOD.
!
!        MODIFIED FROM:
!                               (Version Dated 95188)
!
!        Hardcoded option settings for the Beta release of AERMOD.
!
!        MODIFIED FROM:
!                               (Version Dated 95066)
!
!        "Optionized" version of AERMOD for Developmental Evaluation.
!        Developmental options are selected by use of an additional
!        10-character command line argument, e.g. '1213121111'.
!        If the additional command line argument is not present, then
!        the model will default to the Base Model.  This is equivalent
!        to using an additional command line argument of '1111111111'.
!        Note that the single quotes are not included on the command line.
!                   R.W. Brode, PES, Inc., January 27, 1995
!
!        Version 95066 includes a few minor fixes, some modifications to
!        the EVALFILE output, and the volume source option (mostly untested).
!        The fixes affect the SBL plume reflection option (OPTG2), and two of
!        the inhomogeneity options (OPTD2 and OPTD3).  In the latter cases,
!        the effective wind speed was allowed to be less than the effective
!        sigma-w.  Also, included EVALCART receptors with DISCCART receptors
!        for output purposes (RECTABLE, DAYTABLE, etc., and INPSUM.FOR).
!                   R.W. Brode, PES, Inc., February 16, 1995
!
!        Base Case Model for AERMOD Developmental Evaluation - 12/8/94
!
!        MODIFIED FROM:    ISC2 Short Term Model - ISCST2
!                               (Version Dated 93109)
!
!        MODIFIED FROM:         (Version Dated 92273)
!
!        MODIFIED FROM:         (Version Dated 92062)
!
!        PURPOSE: Controls Overall Flow and Processing of ISCST2 Model
!
!        PROGRAMMED BY: Roger W. Brode
!                       James O. Paumier
!                       Jayant A. Hardikar
!                       Pacific Environmental Services, Inc.
!                       P.O. Box 12077
!                       Research Triangle Park, North Carolina  27709
!
!        DATE:    November 9, 1993
!
!        INPUTS:  Command Line Options
!
!        OUTPUTS: Model Results
!
!========================================================================
!
!     Variable Declarations
      USE MAIN1
      IMPLICIT NONE
      CHARACTER MODNAM*12

      INTEGER :: I , IDSTAT
      SAVE

!     Variable Initializations
      MODNAM = 'MAIN'                                                   !      7
      FATAL = .FALSE.
      RUNERR = .FALSE.

!     Open the Temporary File for Error Messages Generated from the Program
      OPEN (UNIT=IERUNT,FILE='ERRMSG.TMP',STATUS='REPLACE')

!CLC     Command line arguments removed.  Use AERMOD.INP and AERMOD.OUT.
!CLC     Retrieve Input and Output File Names From Command Line,
!CLC     ---   CALL GETCOM
!CL      CALL GETCOM (' AERMOD ',ILEN_FLD,INPFIL,OUTFIL)

!     Open Input and Output Files                           ---   CALL FILOPN
      CALL FILOPN

!     Preprocess Setup Information to Determine Data Storage Needs
      CALL PRESET

      IF ( .NOT.EVONLY ) THEN
!        OPEN The Temporary File to Store Events for EVENT File;
         OPEN (UNIT=ITEVUT,FILE='EVENT.TMP',STATUS='REPLACE')           !      3
!        Initialize the Event Counter
         IEVENT = 0
      ENDIF

!     Allocate SETUP Array Storage
      CALL ALLSETUP                                                     !      3

!     Variable Initializations                              ---   CALL VARINI
      CALL VARINI

!     Process The Model Setup Information                   ---   CALL SETUP
      IF ( EVONLY ) THEN
         CALL EV_SETUP                                                  !      0
      ELSE
         CALL SETUP                                                     !      3
      ENDIF

!     Open file with PVMRM debugging output
      IF ( DEBUG .AND. PVMRM ) THEN                                     !      3
         OPEN (50,FILE='PVMRM.TXT',STATUS='REPLACE')                    !      0
         WRITE (50,9001)
 9001    FORMAT (8X,'DATE',3X,'IREC SRCID',6X,'DISTDOM',4X,'MAXCONC',2X,&
     &           'NUMCONT  O3CONC',6X,'O3MOLES',5X,'NOXMOLES',4X,       &
     &           'BHORIZ',6X,'BVERT',4X,'PLUMEVOL',3X,'PercentNO2')
      ENDIF

!     Write the model options and debug data template to the
!     debug file if MODEL is specified
      IF ( DEBUG ) THEN                                                 !      3
!        Write the title(s) to the debug output file
         WRITE (DBGUNT,100) TITLE1 , TITLE2                             !      0
 100     FORMAT (' Title: ',A68,/'        ',A68/)
!        Write the model options (MODOPS) to the output file
         WRITE (DBGUNT,200) (MODOPS(I),I=1,18)
 200     FORMAT (' OPTIONS: ',/18(1X,A6),/)

         WRITE (DBGUNT,600)
 600     FORMAT (/' NOTE:  The Vert. Terms and associated',             &
     &           ' CHIs are from the LIFT calculations!!!'/)

      ENDIF

!     Open file for GDEP output from gas dry deposition algorithms
      IF ( LDGAS ) OPEN (UNIT=100,FILE='GDEP.DAT',STATUS='REPLACE')     !      3

!     Open file for PDEP output from particle dry deposition algorithms
      IF ( LDPART ) OPEN (UNIT=101,FILE='PDEP.DAT',STATUS='REPLACE')

!     Deallocate Temporary Storage
      DEALLOCATE (IWRK2,STAT=IDSTAT)
      IF ( IDSTAT.NE.0 ) THEN
         WRITE (DUMMY,'(I8)') IDSTAT                                    !      0
         CALL ERRHDL(PATH,MODNAM,'E','298',DUMMY)
      ENDIF
      IF ( .NOT.EVONLY ) THEN                                           !      3
         DEALLOCATE (ZETMP1,ZETMP2,ZHTMP1,ZHTMP2,ZFTMP1,ZFTMP2,         &
     &               STAT=IDSTAT)
         IF ( IDSTAT.NE.0 ) THEN
            WRITE (DUMMY,'(I8)') IDSTAT                                 !      0
            CALL ERRHDL(PATH,MODNAM,'E','298',DUMMY)
         ENDIF
      ENDIF

!     Allocate Array Storage for Results
      CALL ALLRESULT                                                    !      3

!     Determine Number of Setup Messages by Message Type    ---   CALL TERRST
      CALL TERRST

! --- Set up common for PRIME numerical rise algorithm      ---   CALL NUMPR1
      CALL NUMPR1

! --- Set up common for PRIME building cavity model         ---   CALL PRIME1
      CALL PRIME1

      IF ( .NOT.RUN .OR. FATAL .OR. IWRN.GT.0 ) THEN
!        Write Out Summary Of Setup Error/Message Stats     ---   CALL SUMTBL
         WRITE (IOUNIT,9111)                                            !      1
 9111    FORMAT (//2X,'*** Message Summary For AERMOD Model Setup ***'/)
         CALL SUMTBL
      ENDIF

      IF ( FATAL ) THEN                                                 !      3
         WRITE (*,99111)                                                !      1
99111    FORMAT ('+','Fatal Error Occurred During Setup Phase!')
         WRITE (IOUNIT,9112)
 9112    FORMAT (/4X,'**************************************',/4X,      &
     &           '*** SETUP Finishes UN-successfully ***',/4X,          &
     &           '**************************************'/)
      ELSE
         WRITE (IOUNIT,9113)                                            !      2
 9113    FORMAT (/1X,'***********************************',/1X,         &
     &           '*** SETUP Finishes Successfully ***',/1X,             &
     &           '***********************************'/)
      ENDIF

!     Print Summary of the Input Data                       ---   CALL INPSUM
      CALL INPSUM                                                       !      3

!     Write Headers to GDEP.DAT and PDEP.DAT Files for new deposition algorithms
      IF ( LDGAS ) THEN
         WRITE (100,9901)                                               !      0
 9901    FORMAT (1X,'YYMMDDHH',3X,'ISRC',4X,'Ra',12X,'Rb',12X,'Rc',12X, &
     &           'Vdepg')
      ENDIF
      IF ( LDPART ) THEN                                                !      3
         WRITE (101,9902)                                               !      0
 9902    FORMAT (1X,'YYMMDDHH',3X,'ISRC',1X,'ICAT',2X,'Method No.',3X,  &
     &           'Ra',12X,'Rp',12X,'Vg(i)',9x,'Vdep(i)')
      ENDIF

      IF ( .NOT.FATAL .AND. RUN .AND. EVONLY ) THEN                     !      3
!        No Fatal Errors in Setup and RUN Option Selected and EVENT Processing

!        Process The Data For Each Event                    ---   CALL EVLOOP
         CALL EVLOOP                                                    !      0

      ELSEIF ( .NOT.FATAL .AND. RUN .AND. .NOT.EVONLY ) THEN
!        No Fatal Errors in Setup and RUN Option Selected and Normal Processing

!        Reinitialize Results Arrays With Zeroes            ---   CALL RESINI
         CALL RESINI                                                    !      2

!           Initialize Results Arrays from Re-start File    ---   CALL RSINIT
         IF ( RSTINP ) CALL RSINIT

!        Process The Hourly Meteorological Data             ---   CALL HRLOOP
         CALL HRLOOP

         IF ( (ANNUAL .OR. PM10AVE) .AND. .NOT.RUNERR ) THEN
!           Compute averages of the high-fourth-high 24-hr and annual values
            IF ( NUMYRS.GT.0 ) THEN                                     !      0
               DO IGRP = 1 , NUMGRP                                     !      0
                  DO IREC = 1 , NUMREC                                  !      0
                     IF ( PM10AVE ) SUMH4H(IREC,IGRP)                   &
     &                    = SUMH4H(IREC,IGRP)/NUMYRS
                     IF ( ANNUAL ) THEN
                        DO ITYP = 1 , NUMTYP                            !      0
                           ANNVAL(IREC,IGRP,ITYP)                       &
     &                        = SUMANN(IREC,IGRP,ITYP)/NUMYRS
                        ENDDO
                     ENDIF
                  ENDDO
               ENDDO
            ELSE
!              Write Error Message: Number of Years = 0.
               CALL ERRHDL(PATH,MODNAM,'E','480','NUMYRS=0')            !      0
               RUNERR = .TRUE.
            ENDIF
            IF ( NREMAIN.NE.0 ) THEN                                    !      0
!              Write Warning Message: Met Data Remains After End of Last Year
               WRITE (DUMMY,'(I8)') NREMAIN                             !      0
               CALL ERRHDL(PATH,MODNAM,'W','485',DUMMY)
            ENDIF
         ENDIF

         IF ( (PERIOD .OR. ANNUAL) .AND. (.NOT.RUNERR) .AND.            &
     &        NTOTHRS.GT.0 ) THEN
!           PERIOD Average Selected and No Runtime/Meteorology Errors
!              Calculate Period Average Concentrations      ---   CALL PERAVE
            IF ( CONC .AND. PERIOD ) CALL PERAVE                        !      2
            DO ITYP = 1 , NUMTYP
!              Select Highest PERIOD Values by Source Group ---   CALL HIPER
               CALL HIPER                                               !      2
            ENDDO
!              Write PERIOD/ANNUAL Results to Post File     ---   CALL PSTANN
            IF ( ANPOST ) CALL PSTANN                                   !      2
!              Write PERIOD/ANNUAL Results to Plot File     ---   CALL PLTANN
            IF ( ANPLOT ) CALL PLTANN
         ENDIF

         IF ( SEASONHR .AND. .NOT.RUNERR ) THEN                         !      2
            IF ( CONC ) CALL SHAVE                                      !      0
         ENDIF

!           Write Short Term High Values to Plot File       ---   CALL PLOTFL
         IF ( PLFILE .AND. (.NOT.RUNERR) ) CALL PLOTFL                  !      2

!           Print Out Model Results                         ---   CALL OUTPUT
         IF ( .NOT.RUNERR ) CALL OUTPUT

      ENDIF

      CALL HEADER                                                       !      3
      WRITE (IOUNIT,9114)
 9114 FORMAT (/1X,'*** Message Summary : AERMOD Model Execution ***'/)
!     Determine Number of Errors/Messages by Message Type   ---   CALL TERRST
      CALL TERRST
!     Write Summary of Message Stats for Model Execution    ---   CALL SUMTBL
      CALL SUMTBL

      IF ( FATAL .OR. RUNERR ) THEN
         WRITE (IOUNIT,9115)                                            !      1
 9115    FORMAT (/4X,'***************************************',/4X,     &
     &           '*** AERMOD Finishes UN-successfully ***',/4X,         &
     &           '***************************************'/)
      ELSE
         WRITE (IOUNIT,9116)                                            !      2
 9116    FORMAT (/4X,'************************************',/4X,        &
     &           '*** AERMOD Finishes Successfully ***',/4X,            &
     &           '************************************'/)
      ENDIF

      IF ( ERRLST ) THEN                                                !      3
!        OPEN and Write Out Permanent Error Message File    ---   CALL MSGWRT
         OPEN (UNIT=IERWRT,FILE=MSGFIL,STATUS='REPLACE',                &
     &         FORM='FORMATTED')
         CALL MSGWRT
         CLOSE (IERWRT)
      ENDIF

!     Close and Delete The Error Message And EVENT Temporary Files
      CLOSE (IERUNT,STATUS='DELETE')                                    !      3
      CLOSE (ITEVUT,STATUS='DELETE')

      CONTINUE
      END

HyperKWIC - Version 1.00DD executed at 20:00 on  1 Mar 2018  | Personal or Academic or Evaluation User | Free for Non-Commercial, Non-Government Use